module Exercise08 where

import Data.Bits
import Data.List
import System.Random (mkStdGen, randoms, randomIO, Random)
import Data.Ord (comparing)

-- Player is either 1 or -1
type Player = Int

-- A field is just an Int value where the absolute gives the number of pieces on the field
-- and the sign corresponds to the player
-- e.g. -3 would mean there are three blobs in this field of player -1
type Field = Int

type Row = [Field]
type Column = [Field]
-- boards are rectangles represented as a list of rows
type Board = [Row]

-- A position on the board is represented as (row, column)
-- (0,0) is the top left corner, coordinate values increase towards the bottom right
type Pos = (Int, Int)

-- A size represented as (height,width)
type Size = (Int, Int)

-- A strategy takes the player who's move it is, optionally takes a list of double values
-- to allow for probabilistic strategies, takes the current board and gives back the position
-- of the move the player should do
type Strategy = [Double] -> Player -> Board -> Pos
-- A stateful strategy can additionally pass some object between invocations
type StatefulStrategyFunc a = a -> [Double] -> Player -> Board -> (Pos, a)
-- first value is the state object to pass to the first invocation of each game
type StatefulStrategy a = (a, StatefulStrategyFunc a)

-- the position to put a orb to and the resulting board rating
type Move = (Pos, Float)

defaultSize :: (Int, Int)
defaultSize = (9,6)

-- Some useful helper functions
row :: Board -> Int -> Row
row = (!!)

column :: Board -> Int -> Column
column = row . transpose

width :: Board -> Int
width (x : _) = length x
width _       = 0

height :: Board -> Int
height = length

size :: Board -> Size
size b = (height b, width b)

getCell :: Pos -> Board -> Field
getCell (y, x) b = b !! y !! x

-- pretty print a single cell
showCell :: Field -> String
showCell c = "- +" !! succ (signum c) : show (abs c)

-- pretty print the given board
showBoard :: Board -> String
showBoard = unlines . map (unwords . map showCell)

-- print a board to the console
printBoard :: Board -> IO ()
printBoard = putStr . showBoard

-- check if a position is one a board of the given size
isValidPos :: Size -> Pos -> Bool
isValidPos (r, c) (y, x) = y >= 0 && y < r && x >= 0 && x < c

{- x.1 -}

-- Check if the given player can put an orb on the given position
canPlaceOrb :: Player -> Pos -> Board -> Bool
canPlaceOrb p (y, x) b = val == 0 || signum val == signum p
  where 
    val = getCell (y, x) b

-- Check if the given player has won the game,
-- you can assume that the opponent has made at least one move before
hasWon :: Player -> Board -> Bool
hasWon p b = all (==True) [all (==True) [signum c /= -p | c <-r] | r <- b]

-- the list of neighbors of a cell
neighbors :: Size -> Pos -> [Pos]
neighbors (r, c) (y, x) = up ++ right ++ left ++ down
  where
    up = [(y-1, x) | y > 0]
    right = [(y, x+1) | x < c - 1]
    left = [(y, x-1) | x > 0]
    down = [(y+1, x) | y < r - 1]


-- update a single position on the board
-- f: function that modifies the number of orbs in the cell
-- p: player to whom the updated cell should belong
updatePos :: (Int -> Int) -> Player -> Pos -> Board -> Board
updatePos f p (y, x) b = [[if r == y && c == x then newNumb else getCell (r, c) b | c <- [0..snd s -1]] | r <- [0..fst s -1]]
  where 
    newNumb = f (abs (getCell (y, x) b)) * p
    s = size b

{- x.2 -}

-- place an orb for the given player in the given cell
putOrb :: Player -> Pos -> Board -> Board
putOrb p (y, x) b = putOrbRec p False (y, x) b

-- Bool specifying whether the board has been updated or not
-- (only False with the initial call from putOrb)
putOrbRec :: Player -> Bool -> Pos -> Board -> Board
putOrbRec player updated pos board 
  | hasWon player newB = newB 
  | not isFilled = newB 
  | otherwise = foldr (putOrbRec player True) overflowedB nbs
  where 
    newB = if updated then board else updatePos (+1) player pos board 
    nbs = neighbors (size newB) pos 
    isFilled = length nbs <= abs (getCell pos newB)
    overflowedB = foldr (updatePos (+1) player) (updatePos (\x -> x - length nbs) player pos newB) nbs




{- x.3 -}

{-WETT-}
-- Your strategy
strategy :: Strategy
strategy rnds player board = fst (bestMove player board 1)

-- adds state to a strategy that doesn't use it
wrapStrategy :: Strategy -> StatefulStrategy Int
wrapStrategy strat = (0, \s r p b -> (strat r p b, succ s))

-- the actual strategy submissions
-- if you want to use state modify this instead of strategy
-- additionally you may change the Int in this type declaration to any type that is usefully for your strategy
strategyState :: StatefulStrategy Int
strategyState = wrapStrategy strategy


corners :: Board -> [Pos]
corners b = [(0, 0), (0,maxX), (maxY, 0), (maxY, maxX)]
  where
    maxX = width b - 1
    maxY = height b - 1

rateBoard :: Board -> Float
rateBoard board
  | hasWon 1 board = inf
  | hasWon (-1) board = -inf
  | otherwise = sum [sum (modify (row board i)) | i <- [0..height board - 1]] 
              + fromIntegral (sum [getCell pos board | pos <- corners board])         -- corners are valuable i think
    where 
      inf = 1/0
      modify :: [Int] -> [Float]      -- modify the cells by their values
      modify = map (\x -> fromIntegral x :: Float)   -- more orbs per cell 


pickMove :: Player -> [Move] -> Move
pickMove p = maximumBy (comparing (\x -> (fromIntegral p :: Float) * snd x))


getPossibleMovesRated :: Player -> Board -> [Move]
getPossibleMovesRated player board = [move y x | x <- [0..width board - 1], y <- [0..height board -1], canPlaceOrb player (y, x) board]
  where 
    move y x = ((y, x), rateBoard (putOrb player (y, x) board))

getPossiblePos :: Player -> Board -> [Pos]
getPossiblePos player board = [(y, x) | x <- [0..width board - 1], y <- [0..height board -1], canPlaceOrb player (y, x) board]


-- recursively picks the best move
-- the Int counts how many recursion levels to go deeper are left
bestMove :: Player -> Board -> Int -> Move
bestMove player board 0 = pickMove player (getPossibleMovesRated player board) 
bestMove player board lvl = pickMove player [(pos, snd (bestMove (-player) (withOrb pos) (lvl-1))) | pos <- getPossiblePos player board]
  where
    withOrb pos = putOrb player pos board


{-TTEW-}

-- Simulate a game between two strategies on a board of the given size and
-- returns the state of the board before each move together with the player that won the game
play :: [Int] -> Size -> StatefulStrategy a -> StatefulStrategy b -> [(Board, Pos)]
play rss (r, c) (isa, sa) (isb, sb) = go rss isa sa isb sb 1 0 (replicate r (replicate c 0))
  where
    -- type signature is necessary, inferred type is wrong!
    go :: [Int] -> a -> StatefulStrategyFunc a -> b -> StatefulStrategyFunc b -> Player -> Int -> Board -> [(Board, Pos)]
    go (rs:rss) stc sc stn sn p n b
      | won       = []
      | valid     = (b, m) : go rss stn sn st' sc (-p) (succ n) (putOrb p m b)
      | otherwise = []
      where
        won      = n > 1 && hasWon (-p) b
        (m, st') = sc stc (mkRandoms rs) p b
        valid    = isValidPos (size b) m && canPlaceOrb p m b

-- Play a game and print it to the console
playAndPrint :: Size -> StatefulStrategy a -> StatefulStrategy b -> IO ()
playAndPrint size sa sb = do
  seed <- randomIO
  -- let seed = 42
  let moves = play (mkRandoms seed) size sa sb
  putStr $
    unlines (zipWith showState moves $ cycle ['+', '-']) ++ "\n" ++
    (case length moves `mod` 2 of { 1 -> "Winner: +"; 0 -> "Winner: -" }) ++ "\n" ++
    "View at https://vmnipkow16.in.tum.de/christmas2020/embed.html#i" ++ base64 (1 : t size ++ concatMap (t . snd) moves) ++ "\n"
  where
    showState (b, pos) p = showBoard b ++ p : " places at " ++ show pos ++ "\n"
    t (a, b) = [a, b]

mkRandoms :: Random a => Int -> [a]
mkRandoms = randoms . mkStdGen

base64 :: [Int] -> String
base64 xs = case xs of
  []            -> ""
  [a]           -> f1 a : f2 a 0 : "=="
  [a, b]        -> f1 a : f2 a b : f3 b 0 : "="
  a : b : c : d -> f1 a : f2 a b : f3 b c : f4 c : base64 d
  where
    alphabet = (!!) "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
    f1 a     = alphabet $ shiftR a 2
    f2 a b   = alphabet $ shiftL (a .&. 3 ) 4 .|. shiftR b 4
    f3 b c   = alphabet $ shiftL (b .&. 15) 2 .|. shiftR c 6
    f4 c     = alphabet $ c .&. 63